ЛР7 - Объектно-ориентированное программирование
Лабораторная работа №7
Объектно-ориентированное программирование
Цель работы – овладение практическими приемами и навыками разработки и создания программ посредством иерархически связанных классов.
- Теоретическая часть
1.1. Введение
Объектно-ориентированное программирование (ООП) - это результат естественной эволюции более ранних методологий программирования. Оно более структурировано и более модульно и абстрактно, чем традиционное программирование. Потребность в ООП связана со стремительным усложнением приложений и отсюда как следствие недостаточной надежностью программ и выразительными способностями языков программирования.
ООП - это моделирование объектов посредством иерархически связанных классов. Малозначащие детали объекта скрыты от нас, и если мы даем команду, например, переместить объект, то он "знает", как он это делает. Переход от традиционного программирования к ООП на начальном этапе характерен тем, что под объектами в программе подразумеваются конкретные физические объекты. В этом случае легче дается понимание различных действий над ними. В качестве примера выберем простые графические фигуры, поскольку каждая фигура представляет реальный объект на экране. Его всегда можно отобразить и тем самым проверить моделируемые действия над объектом в явном виде. После того как определены простейшие графические объекты, достаточно легко можно формировать более сложные на основе уже имеющихся. В ООП такому сложному графическому объекту соответствует список примитивных объектов, к которому применимы все те же действия, что и к составляющим его элементам: отображение, стирание с экрана, перемещение в заданном направлении.
ООП опирается на три основных понятия:
· инкапсуляция;
Рекомендуемые материалы
· наследование;
· полиморфизм.
1.2.Объект и инкапсуляция
В Паскале объект очень похож на запись, которая является упаковкой для соединения нескольких взаимосвязанных элементов данных вместе, под одним именем. Данные определяют свойства объекта. С другой стороны, объект имеет свое поведение, определяемое процедурами и функциями этого объекта.
Инкапсуляция - объединение данных с процедурами и функциями для создания нового типа данных - объекта. Связанные с объектом процедуры и функции называются методами. Таким образом, поля данных объекта - это то, что объект "знает", его методы - это то, что объект делает.
Для описания объектов используется зарезервированное слово OBJECT. Описание объекта помещается в разделе описания типов. Вначале описываются все инкапсулированные в объекте данные, а затем - методы доступа к этим данным. Сами методы при описании объекта не раскрываются, указываются лишь заголовки. Методы описываются ниже по тексту программы.
В рассмотренном ниже примере тип объекта "координаты точки" может быть определен следующим образом:
Type Location = Object
X,Y: Integer; {данные}
Procedure Init(InitX, InitY: Integer); {заголовки методов}
Function GetX: Integer;
Function GetY: Integer;
End;
{описание методов}
Procedure Location.Init(InitX, InitY: Integer);
Begin
X:=InitX;
Y:=InitY;
End;
Function Location.GetX: Integer;
Begin
GetX:=X; {получение координаты Х текущей позиции на экране}
End;
Function GetY: Integer;
Begin
GetY:=Y; {получение координаты У текущей позиции на экране}
End;
1.3. Иерархия объектов и наследование
Предположим, что мы хотим высветить точку на экране в позиции, описанной типом LOCATION. Определим тип POINT, который содержит булевское поле, указывающее, светится ли пиксель в данной позиции. Так как все точки должны содержать позицию, мы говорим, что тип POINT - это тип, порожденный типом LOCATION. POINT наследует все, что имеет LOCATION и добавляет в него нечто новое (признак светимости):
Type Location = Object
X,Y: Integer; {данные}
Procedure Init(InitX, InitY: Integer); {заголовки методов}
Function GetX: Integer;
Function GetY: Integer;
End;
Point = Object(Location)
Visible: Boolean;
End;
В качестве примера построим иерархию объектов Координаты - Точка - Квадрат (Lоcation - Point - Square). Удобно определять объекты в модулях, причем тип объекта описывается в интерфейсной части модуля, а тела процедур-методов типа объекта - в разделе модуля Implementation.
Пример 7.1. Этот модуль определяет объекты Lоcation, Point и Square.
unit obj1_OOP;
interface
uses graph;
type location = object
x,y: integer;
procedure init(X1,Y1:integer);
function getX: integer;
function getY: integer;
end;
point = object(location)
procedure init(X1,Y1:integer);
visible: boolean;
procedure show;
procedure hide;
procedure shift(X1,Y1:integer);
end;
square = object(point)
side: integer;
procedure init(X1,Y1,side1:integer);
procedure show;
procedure hide;
procedure shift(X1,Y1:integer);
procedure explode(Step:integer);
end;
{-----------------------------------------}
IMPLEMENTATION
procedure location.init(X1,Y1:integer);
begin
x:=X1;
y:=Y1;
end; {location.init}
function location.getX:integer;
begin
getX:=x;
end; {location.getX}
function location.getY:integer;
begin
getY:=y;
end; {location.getY}
procedure point.init(X1,Y1:integer);
begin
location.init(X1,Y1);
end; {point.init}
procedure point.show;
begin
visible:=true;
putpixel(x,y,getcolor);
end; {point.show}
procedure point.hide;
begin
visible:=false;
putpixel(x,y,getbkcolor);
end; {point.hide}
procedure point.shift(X1,Y1:integer);
begin
hide;
init(X1,Y1);
show;
end; {point.shift}
procedure square.init(X1,Y1,side1:integer);
begin
side:=side1;
point.init(X1,Y1);
end; {square.init}
procedure square.show;
begin
visible:=true;
rectangle(X-side div 2, X- side div 2, X+side div 2, Y+ side div 2);
end; {sguare.show}
procedure square.hide;
var temp:word;
begin
temp :=getcolor;
setcolor(getbkcolor);
show;
visible:=false;
Setcolor(temp);
end; {sguare.hide}
procedure square.shift(X1,Y1:integer);
begin
hide;
X:=X1;
Y:=Y1;
show;
end; {sguare.shift}
procedure square.explode(step:integer);
begin
hide;
inc(side,step);
show;
end;
end.
Чтобы использовать эти типы объектов и методы, в своей программе достаточно определить экземпляры типа Point и Square:
program ex1_OOP;
uses crt,graph,obj1_OOP;
var gm,gd :integer;
XP :point;
XS :square;
I :word;
Begin
gd:=detect;
InitGraph(gd,gm,'C:BPBGI');
if GraphResult<>GrOk then Halt(1);
with XP do
begin
init(100,100);
show;
readln;
shift(200,200);
readln;
hide;
end;
with XS do begin
init(100,100,50);
show;
readln;
shift(200,200);
readln;
for i:= 1 to 20 do
begin
explode(10);
delay(200);
end;
readln;
hide;
end;
closeGraph;
End.
В этом примере инициализируется точка, затем она показывается на экране, перемещается в новое место и прячется. Затем инициализируется квадрат, показывается на экране, в 20 раз увеличивает свои линейные размеры на 5 точек и стирается.
Когда родительский тип определен, наследуемые правила могут быть заменены (а могут и использоваться). Для замены унаследованного правила просто определите новое правило с тем же именем, как и унаследованное, но с другим телом и (при необходимости) с другим набором параметров. Логика компилятора в решении вызовов методов такова: компилятор сначала ищет метод с таким именем, определенный в пределах типа объекта. Тип Square определяет методы с именами Init, Show, Hide, Shift и Explode. Если тип Square должен вызвать один из этих методов, компилятор заменит этот вызов адресом одного из собственных методов объекта Square.
Если методов с таким именем не определено в пределах типа объекта, компилятор переходит вверх, к типу непосредственного прародителя, и ищет метод, имя которого вызвано в пределах этого типа. Если метод с таким именем найден, адрес метода прародителя заменяет имя в исходном коде метода потомка. Если же метод по такому имени не найден, компилятор продолжит поиск метода вверх до следующего прародителя. Если компилятор попадает в самый верхний (первый) тип объекта, он выдает сообщение об ошибке, показывающее, что такой метод не определен.
Пользователь может создавать новых потомков и не имея исходного кода Unit (это важно в коммерческих приложениях). Следующий пример иллюстрирует эту возможность, порождая новый объект PaintSquare (закрашенный квадрат), базируясь только на тексте секции Interface для модуля Obj1_OOP.
Unit obj2_OOP;
Interface
Uses Graph, obj1_OOP;
Type PaintSquare = Object(Square)
SquareColor: Word;
Procedure Init(X1,Y1,Side1,Color:Integer);
Procedure Show;
Procedure Hide;
Procedure Shift(X1,Y1:Integer);
Procedure Explode(Step:Integer);
End;
Implementation
Procedure PaintSquare.Init(X1,Y1,Side1,Color:Integer);
Begin
Square.Init(X1,Y1,Side1);
SquareColor :=Color;
End;
Procedure PaintSquare.Show;
Var Temp : Word;
Begin
Square.Show;
Temp:=GetColor;
SetFillStyle(SolidFill, SquareColor);
FloodFill(X,Y,Temp);
SetColor(Temp);
End;
Procedure PaintSquare.Hide;
Begin
SetFillStyle(SolidFill,GetBkColor);
FloodFill(X,Y,GetBkColor);
Square.Hide;
End;
Procedure PaintSquare.Shift(X1,Y1 : Integer);
Begin
Hide;
Init(X1,Y1,Side,SquareColor);
Show;
End;
Procedure PaintSquare.Explode(Step : Integer);
Begin
Hide;
Inc(Side,Step);
Init(X,Y,Side,SquareColor);
Show;
End;
End.
Используется модуль аналогично предыдущему. В следующем примере инициализируется закрашенный квадрат, затем он показывается на экране, перемещается на новое место и, наконец в 20 раз увеличивает линейные размеры на 5 точек, а затем возвращается в исходное состояние путем последовательного уменьшения.
Program EX2_OOP;
Uses Crt, Graph, obj2_OOP;
var gd,gm : integer;
XPS : PaintSquare;
I : Word;
begin
gd:=Detect;
InitGraph(gd,gm,'C:BPBGI');
If graphResult<>GrOk then Halt(1);
With XPS do
Begin
Init(100,100,50,14);
Show;
Readln;
Shift(200,200);
Readln;
For i:=1 to 20 do Begin
Explode(5);
Delay(200);
End;
Readln;
For i:=1 to 20 do Begin
Explode(-5);
Delay(200);
End;
Readln;
CloseGraph;
End;
End.
1.5. Виртуальные методы и полиморфизм
Все методы, которые мы рассматривали до этого, были статическими, т.е. компилятор размещает их и разрешает все ссылки во время компиляции. В Турбо Паскале существует возможность связывания данных с методами на этапе выполнения программы, такое связывание называется поздним. При позднем связывании используются так называемые виртуальные методы. Виртуальные методы реализуют чрезвычайно мощное средство для обобщения, которое называется полиморфизмом.
Полиморфизм - свойство, позволяющее называть разные алгоритмические действия одним именем. Такое действие совместно используется в иерархии объектов, причем каждый объект в этой иерархии реализует это действие своими собственными, пригодными для него способами.
Метод делается виртуальным, когда за его определением в типе объекта ставится служебное (зарезервированное) слово Virtual. Надо запомнить, что, если вы определяете метод в родительском типе как Virtual, все методы с тем же именем в любом из потомков также должны быть описаны как Virtual.
Вот как может произойти виртуализация рассмотренных выше графических объектов:
Unit obj3_OOP;
Interface
Uses Graph;
Type Location = Object
X,Y : Integer;
Procedure Init(X1,Y1 : Integer);
Function GetX : Integer;
Function GetУ : Integer;
End;
Point = Object(Location)
Visible : Boolean;
Constructor Init(X1,Y1 : integer);
Procedure Show; Virtual;
Procedure Hide; Virtual;
Procedure Shift(X1,Y1 : integer); Virtual;
Destructor LastStep; Virtual;
End;
Square = Object(Point)
Side : integer;
Constructor Init(X1,Y1,Side1 : Integer);
Procedure Show; Virtual;
Procedure Hide; Virtual;
Destructor LastStep; Virtual;
End;
PaintSquare = Object(Square)
SquareColor : Word;
Constructor Init(X1,Y1,Side1,Color : Integer);
Procedure Show; Virtual;
Procedure Hide; Virtual;
Destructor LastStep; Virtual;
End;
IMPLEMENTATION
Procedure Location.Init(X1,Y1 : integer);
Begin
X:=X1;
Y:=Y1;
End;
Function Location.GetX : Integer;
Begin
GetX:=X;
End;
Function Location.GetY : Integer;
Begin
GetY:=Y;
End;
Constructor Point.Init(X1,Y1 : Integer);
Begin
Location.Init(X1,Y1);
End;
Procedure Point.Show;
Begin
Visible:=True;
PutPixel(X,Y,GetColor);
End;
Procedure Point.Hide;
Begin
Visible:=False;
PutPixel(X,Y,GetBkColor);
End;
Procedure Point.Shift(X1,Y1: Integer);
Begin
Hide;
X:=X1;Y:=Y1;
Show;
End;
Destructor Point.LastStep;
Begin
End;
Constructor Square.Init(X1,Y1,Side1 : integer);
Begin
Side:=Side1;
Point.Init(X1,Y1);
end;
Procedure Square.Show;
Begin
Visible:=True;
Rectangle(X-Side div 2, Y-Side div 2,
X+Side div 2, Y+Side div 2);
End; {Show}
Procedure Square.Hide;
Var Temp : Word;
Begin
Temp:=GetColor;
SetColor(GetBkColor);
Show;
Visible:=False;
Setcolor(Temp);
End; {hide}
Destructor Square.LastStep;
Begin
End;
{-------------------------------------------}
Constructor PaintSquare.Init(X1,Y1,Side1,Color:Integer);
Begin
Square.Init(X1,Y1,Side1);
SquareColor:=Color;
End;
Procedure PaintSquare.Show;
Var Temp : Word;
Begin
Square.Show;
Temp:=GetColor;
SetFillStyle(SolidFill, SquareColor);
FloodFill(X,Y,Temp);
SetColor(Temp);
End;
Procedure PaintSquare.Hide;
Begin
SetFillStyle(SolidFill,GetBkColor);
FloodFill(X,Y,GetBkColor);
Square.Hide;
End;
Destructor PaintSquare.LastStep;
Begin
End;
End.
Прежде всего, отметим, что метод Shift уходит из определения типов объекта Square и объекта PainSquare . Он наследуется от Point, и все вложенные вызовы методов переходят к Square и PaintSquare.
Отметим также использование нового служебного слова Constructor (конструктор), которое заменило зарезервированное слово Procedure для Point.Init, Square.Init и PainSquare.Init. Все типы объектов, которые имеют виртуальные правила, должны иметь конструктор. Конструктор - это особый вид процедуры, который выполняет некоторую установочную работу для механизма виртуальных методов. Каждый отдельный экземпляр объекта должен быть инициализирован отдельным вызовом конструктора.
Что же делает конструктор? Для каждого типа объекта компилятор создает так называемую таблицу виртуальных методов (ТВМ), в которой содержится размер типа объекта и адреса точек входа всех виртуальных методов. Каждый экземпляр объекта пользуется единственной для объектов данного типа таблицей. Конструктор же устанавливает связь между экземпляром, вызывающим этот конструктор, и ТВМ данного типа объекта. В момент обращения к конструктору в специальное поле объекта заносится адрес нужной ТВМ, в результате чего все виртуальные методы получают доступ к нужным полям. Конструктор может быть пустым (не иметь исполняемых операторов), но объект будет инициализирован правильно.
Destructor предназначен для выполнения различных операций, связанных с ликвидацией объекта (исключение его из списка, задание параметров, очистки данных и т.д.). Деструктор, как правило, наследуется потомками и обычно бывает виртуальным.
Для того чтобы показать использование полиморфных объектов вместе с поздним связыванием, напишем программу, которая содержит универсальную процедуру перетаскивания графических фигур по экрану. По правилу совместимости типов эта процедура перемещает любую фигуру, порожденную от объекта Point. Перемещение производится при нажатии на клавиши-стрелки. Для окончания перемещения следует нажать на клавишу Esc.
program ex3_OOP;
uses crt,graph,obj3_OOP;
var gm,gd:Integer;
XP:Point;
XS:Square;
XPS:PaintSquare;
Procedure DragAny(Var AnyX : Point);
{Процедура перемещает любую фигуру, порожденную от объекта Point}
Const Left = #75; { ¬, код клавиш управления курсором}
Right = #77; { ® }
Up = #72; { }
Down = #80; { ¯ }
Gap = 11; {сдвиг при движении на столько точек}
Var
Ch : Char;
StartX,StartY : Integer;
Begin
AnyX.Show;
StartX:=AnyX.GetX;
StartY:=AnyX.GetY;
Repeat
Ch:=ReadKey;
If Ch=#0 Then Begin
Ch:=ReadKey;
Case Ch Of
Left : Dec(StartX,Gap);
Right : Inc(StartX,Gap);
Up : Dec(StartY,Gap);
Down : Inc(StartY,Gap);
End;
AnyX.Shift(StartX,StartY);
End;
Until Ch=#27; {окончание перемещения - клавиша Esc}
End;
{-----------------------------------}
Begin
Gd:=Detect;
InitGraph(Gd,Gm,'');
if GraphResult<>GrOk then Halt(1);
XP.Init(320,170); {инициализируется точка}
DragAny(XP);
XP.Hide;
XS.Init(320,170,50); {инициализируется квадрат}
XS.Show;
DragAny(XS);
XS.Hide;
XPS.Init(320,170,50,14); {инициализируется окрашенный квадрат}
DragAny(XPS);
XPS.Hide;
CloseGraph;
End.
Пример позднего связывания демонстрирует использование процедуры Shift объектами XS (квадрат) и XPS (окрашенный квадрат). Объекты этого типа наследуют метод Shift от Point. Метод Point.Shift обращается к виртуальным методам Point.Show и Point.Hide. Одноименные методы Show и Hide имеют типы Square и PaintSquare. С помощью ТВМ родительский метод Point.Shift "узнал" о существовании виртуальных методов Square.Show,Square.Hide, PaintSquare.Show и PaintSquare.Hide и использовал именно их при обращении к Square.Shift и PaintSquare.Shift. Поэтому на экране перемещаются соответственно точка, квадрат и окрашенный квадрат. Это и есть пример полиморфизма (перемещение разных фигур одним методом Shift).
2. Демонстрационные примеры
Пример 7.2.
program LAST_PROGRAM_BY_PASCAL;
{point - line -PerecrestLine }
uses crt,graph;
type
TCoord=object {координаты объекта}
x,y:integer;
constructor Init(ax,ay:integer); end;{специальный тип процедуры , которая выполняет некоторую установочную работу для механизма виртуальных методов. Более того, конструктор должен вызываться перед вызовом любого виртуального метода. Вызов виртуального метода без предварительного вызова конструктора может привести к блокированию системы, а у компилятора нет способа проверить порядок вызова методов.
Каждый экземпляр объекта должен инициализироваться отдельно вызовом конструктора. Недостаточно инициализировать один экземпляр объекта и затем присваивать этот экземпляр другим.}
constructor TCoord.Init;
begin
x:=ax;
y:=ay;
end;
type TPixel=object (TCoord) {дочерний объект , объекта TCoord }
color:integer; {новое свойство дочернего объекта}
constructor Init (ax,ay:integer;acolor:integer);
procedure Draw; {метод - рисование}
end;
constructor TPixel.Init; {реализационная часть нового объекта}
begin
inherited Init (ax,ay);{позволяет вызывать методы предка без указания имени типа предка и точки. Это очень пригодиться при использовании большой иерархии, когда запомнить все связи типа «предок-потомок» невозможно.}
color:=acolor;
end;
procedure TPixel.Draw;
begin
putpixel(x,y,color);{закрашивает пиксель с заданными координатами в цвет color}
end;
type TLine=object (TCoord)
l:integer;
constructor Init (ax,ay:integer;al:integer);
procedure Draw; virtual;
end;
constructor TLine.init;
begin
inherited init(ax,ay);
l:=al;
end;
procedure TLine.Draw;
begin
line (x,y,x+round(l/sqrt(2)),y+round(l/sqrt(2)));
end;
type TPline=object (TLine) {пересечение линий}
constructor Init(ax,ay,al:integer);
procedure Draw;virtual;
end;
constructor TPLine.Init;
begin
inherited init(ax,ay,al);
end;
procedure TPline.Draw;
begin
line (x,y,x+round(l/sqrt(2)),y+round(l/sqrt(2)));
line (x+round(l/sqrt(2)),y,x,y+round(l/sqrt(2)));
end;
var a:Tline;
b:TPLine;
c:TPixel;
gd,gm:integer;
begin
gd:=detect;
initgraph(gd,gm,'');
a.init(100,100,50);
a.Draw;
b.init(200,200,50);
b.draw;
c.init(300,300,5);
c.draw;
readln;
closegraph; end.
3. Задачи, для самостоятельного решения
Задача 1. Построить иерархию объектов. Последовательно отобразить объекты, сдвинуть, изменить размеры, спрятать:
Координаты - точка - горизонтальная линия - горизонтально-вертикальное перекрестье.
Задача 2. Построить иерархию объектов. Последовательно отобразить объекты, сдвинуть, изменить размеры, спрятать:
Координаты - точка - наклонная под углом 45 градусов линия - наклонное перекрестье.
Задача 3. Построить иерархию объектов. Последовательно отобразить объекты, сдвинуть, изменить размеры, спрятать:
Координаты - точка - окружность - дуга (процедура Arc).
Задача 4. Построить иерархию объектов. Последовательно отобразить объекты, сдвинуть, изменить размеры, спрятать:
Координаты - точка - эллипс (процедура FillEllipse) - эллиптическая дуга (процедура Ellipse).
Задача 5. Построить иерархию объектов. Последовательно отобразить объекты, сдвинуть, изменить размеры, спрятать:
Координаты - точка - окружность - сектор (процедура PieSlise).
Задача 6. Построить иерархию объектов. Последовательно отобразить объекты, сдвинуть, изменить размеры, спрятать:
Координаты - точка - сектор (процедура PieSlise) - эллиптическая дуга (процедура Ellipse).
Задача 7. Построить иерархию объектов. Последовательно отобразить объекты, сдвинуть, изменить размеры, спрятать:
Координаты - точка - прямоугольник (процедура Rectangle) - трехмерная полоса (процедура Bar3D).
Задача 8. Построить иерархию объектов. Последовательно отобразить объекты, сдвинуть, изменить размеры, спрятать:
Координаты - точка - заштрихованный эллипс (процедура FillEllipse) - заштрихованный сектор (процедура Sector).
Задача 9. Построить иерархию объектов. Последовательно отобразить объекты, сдвинуть, изменить размеры, спрятать:
Координаты - точка - окружность - заштрихованный сектор (процедура Sector).
Задача 10. Построить иерархию объектов. Последовательно отобразить объекты, сдвинуть, изменить размеры, спрятать:
Координаты - точка - окружность - эллиптическая дуга (процедура Ellipse).
Задача 11. Простые объекты.
Описать объект, включающий заданные поля и методы. Написать программу, которая создает массив объектов и содержит процедуры, работающие с указанными структурами.
Объект - слово. Параметры: текст, длина. Методы: конструктор, определяющий поле текста и длину, и процедура, определяющая количество гласных букв. Определить процент гласных букв в предложении.
Задача 12. Простые объекты.
Описать объект, включающий заданные поля и методы. Написать программу, которая создает массив объектов и содержит процедуры, работающие с указанными структурами.
Объект - слово. Параметры: текст, длина. Методы: конструктор, определяющий поле текста и длину, и процедура, определяющая количество согласных букв. Определить процент гласных букв в предложении.
Задача 13. Простые объекты.
Описать объект, включающий заданные поля и методы. Написать программу, которая создает массив объектов и содержит процедуры, работающие с указанными структурами.
Объект - слово. Параметры: текст, длина. Методы: конструктор, определяющий поле текста и длину, и процедура, определяющая количество слов, содержащих наибольшее количество гласных букв. Определить процент таких слов в предложении.
Задача 14. Простые объекты.
Описать объект, включающий заданные поля и методы. Написать программу, которая создает массив объектов и содержит процедуры, работающие с указанными структурами.
Объект - слово. Параметры: текст, длина. Методы: конструктор, определяющий поле текста и длину, и процедура, определяющая количество слов, содержащих наибольшее количество согласных букв. Определить процент таких слов в предложении.
Задача 15. Простые объекты.
Описать объект, включающий заданные поля и методы. Написать программу, которая создает массив объектов и содержит процедуры, работающие с указанными структурами.
Объект - слово. Параметры: текст, длина. Методы: конструктор, определяющий поле текста и длину, и процедура, определяющая количество слов наибольшей длины. Определить процент таких слов в предложении.
Задача 16. Простые объекты.
Описать объект, включающий заданные поля и методы. Написать программу, которая создает массив объектов и содержит процедуры, работающие с указанными структурами.
Объект - слово. Параметры: текст, длина. Методы: конструктор, определяющий поле текста и длину, и процедура, определяющая количество слов наименьшей дины. Определить процент таких слов в предложении.
Задача 17. Простые объекты.
Описать объект, включающий заданные поля и методы. Написать программу, которая создает массив объектов и содержит процедуры, работающие с указанными структурами.
Объект - предложение. Параметры: массив слов (n<10) и их количество. Методы: конструктор и процедура, определяющая количество слов, длиннее 5 букв. Определить процент слов длиннее 5 букв в заданном тексте.
Задача 18. Простые объекты.
Описать объект, включающий заданные поля и методы. Написать программу, которая создает массив объектов и содержит процедуры, работающие с указанными структурами.
Объект - предложение. Параметры: массив слов (n<10) и их количество. Методы: конструктор и процедура, определяющая количество слов, начинающихся с согласных букв. Определить отношение количества слов, начинающихся с согласных букв в заданном тексте, к количеству слов, начинающихся с гласных букв.
Задача 19. Простые объекты.
Описать объект, включающий заданные поля и методы. Написать программу, которая создает массив объектов и содержит процедуры, работающие с указанными структурами.
Объект - предложение. Параметры: массив слов (n<10) и их количество. Методы: конструктор и процедура, определяющая количество слов, начинающихся с гласных букв. Определить отношение количества слов, начинающихся с гласных букв в заданном тексте, к количеству слов, начинающихся с согласных букв.
Задача 20. Простые объекты.
Описать объект, включающий заданные поля и методы. Написать программу, которая создает массив объектов и содержит процедуры, работающие с указанными структурами.
Объект - слово. Параметры: текст, длина, количество согласных букв. Методы: конструктор, определяющий поле текста и длину, и процедура, определяющая количество гласных букв. Определить количество слов в предложении, в которых согласных букв больше, чем гласных.
Задача 21. Простые объекты.
Описать объект, включающий заданные поля и методы. Написать программу, которая создает массив объектов и содержит процедуры, работающие с указанными структурами.
Объект - слово. Параметры: текст, длина, количество гласных букв. Методы: конструктор, определяющий поле текста и длину, и процедура, определяющая количество согласных букв. Определить количество слов в предложении, в которых гласных букв больше, чем согласных.
Задача 22. Простые объекты.
Описать объект, включающий заданные поля и методы. Написать программу, которая создает массив объектов и содержит процедуры, работающие с указанными структурами.
Объект - предложение. Параметры: массив слов (n<10) и их количество. Методы: конструктор и процедура, определяющая количество слов 'Тверь' в предложении. Определить процент таких слов в предложении.
Задача 23. Простые объекты.
Описать объект, включающий заданные поля и методы. Написать программу, которая создает массив объектов и содержит процедуры, работающие с указанными структурами.
Объект - строительство дома. Параметры: объем работ (в денежном отношении) и процент готовности объекта. Методы: конструктор и процедура, определяющая объем невыполненных работ. Определить самое законченное строительство.
Бесплатная лекция: "9 Порождающие системы" также доступна.
Задача 24. Простые объекты.
Описать объект, включающий заданные поля и методы. Написать программу, которая создает массив объектов и содержит процедуры, работающие с указанными структурами.
Объект - адрес. Параметры: массив адресов (n<10) и их количество. Методы: конструктор и процедура, определяющая адресатов, проживающих в каждом городе и их процентное соотношение.
Задача 25. Простые объекты.
Описать объект, включающий заданные поля и методы. Написать программу, которая создает массив объектов и содержит процедуры, работающие с указанными структурами.
Объект - фотообъектив. Параметры: массив фотообъектив (n<10) и их количество. Методы: конструктор и процедура, определяющая объективы, фокусное расстояние которых - 100 и 120 мм, диаметр равен 80 мм, а материал - LiF и их процентное соотношение.