45186 (664345), страница 2
Текст из файла (страница 2)
(slot name (type STRING))
(slot age (type NUMBER) (default 18))
)
Каждое определение шаблона состоит из произвольного имени шаблона, необязательного комментария и некоторого количества определений слотов. Слот включает поле данных, например name, и тип данных, например STRING. Можно указать и значение по умолчанию, как в приведенном выше примере.
Если в программу включено приведенное выше определение шаблона, то выражение
(deffacts students
(student (name fred))
(student (name freda) (age 19))
)
приведет к тому, что в базу фактов после выполнения команды reset будет добавлено
(student (name fred) (age 18))
(student (name freda) (age 19))
А.2.5. Определение функций
В языке CLIPS функции конструируются примерно так же, как в языке LIPS. Существенное отличие состоит в том, что переменные должны иметь префикс ?, как это показано в приведенном ниже определении.
(deffunction hypotenuse (?a ?b)
(sqrt (+ (* ?a ?a) (* ?b ?b))
)
Формат определения функции в CLIPS следующий:
(deffunction ( …..)
…………….
)
Функция возвращает результат последнего выражения в списке.
Иногда выполнение функции имеет побочные эффекты, как в приведенном ниже примере.
(deffunction init (?day)
(reset)
(assert (today is ?day))
)
В результате после запуска функции на выполнение командой
CLIPS> (init Sunday)
Будет выполнена команда reset и, следовательно, очищена база фактов, а затем в нее будет включен новый факт (today is Sunday).
А.3. ОБЪЕКТНО-ОРИЕНТИРОВАННЫЕ СРЕДСТВА В CLIPS
Использование объектно-ориентированных средств в CLIPS позволяет значительно упростить программирование правил, поскольку для обновления данных можно применять механизм передачи и обработки сообщений методами классов. В этом разделе мы продемонстрируем, как это делается на примере, который моделирует правила обращения с полуавтоматическим пистолетом.
Первым делом определим класс pistol, в котором будут перечислены свойства, необходимые для моделирования.
(defclass pistol
(is-a USER)
(role concrete)
(pattern-match reactive)
(slot safety (type SYMBOL) (create-accessor read-write))
(slot slide (type SYMBOL) (create-accessor read-write))
(slot hammer (type SYMBOL) (create-accessor read-write))
(slot chamber (type INTEGER) (create-accessor read-write))
(slot magazine (type SYMBOL) (create-accessor read-write))
(slot rounds (type INTEGER) (create-accessor read-write))
)
Первые три слота – системные. Они нужны объектно-ориентированной надстройке CLIPS (COOL-CLIPS object-oriented language). Эти слоты COOL извещают о том, что
-
pistol – это пользовательский класс;
-
pistol является конкретным классом, т.е. возможно создание экземпляров этого класса (альтернативный тип – абстрактный класс, который играет ту же роль, что и виртуальный класс в C++);
-
экземпляры класса pistol могут быть использованы в качестве объектов данных, которые можно сопоставлять с условиями в правилах и использовать в действиях, определенных правилами.
Следующие пять слотов представляют свойства и члены данных класса:
-
слот safety (предохранитель) может содержать символ on или off;
-
слот slide (затвор) может содержать значение forward или back, т.е. хранит информацию о положении затвора;
-
слот hammer (курок) содержит информацию о состоянии курка , back или down;
-
слот chamber (патронник) содержит значение 1 или 0, в зависимости от того, есть ли патрон в патроннике;
-
слот magazine (обойма) может содержать значение in или out, в зависимости от того, вставлена ли обойма;
-
слот rounds (патроны) содержит текущее количество патронов в обойме.
Для того чтобы иметь возможность записывать в слот новое значение или считывать текущее, нужно разрешить формирование соответствующих функций доступа через фацет create-accessor. Теперь сформируем экземпляр класса pistol с помощью следующего выражения:
(definstances pistols
(PPK of pistol
(safety on)
(slide forward)
(hammer down)
(chamber 0)
(magazine out)
(rounds 6)
)
)
Этот экземпляр, PPK, правильно уложен – обойма вынута из рукоятки, пистолет установлен на предохранитель, затвор в переднем положении, курок опущен, а патронник пуст. В обойме имеется 6 патронов.
Теперь, имея в программе определение класса и сформировав экземпляр класса, разработаем правила и обработчики сообщений, с помощью которых можно описать отдельные операции обращения с пистолетом и стрельбы из него. Для этого сначала разработаем шаблон задачи. Желательно отслеживать две вещи:
-
есть ли патрон в патроннике;
-
произведен ли выстрел.
Для этого можно использовать следующий шаблон:
(deftemplate range-test
(field check (type SYMBOL) (default no))
(field fired (type SYMBOL) (default no))
)
Первое правило будет устанавливать в рабочую память программы задачу range-test.
(defrule start
(initial-fact)
=>
(assert (range-test))
)
При активизации этого правила в рабочую память будет добавлено
(range-test (check no) (fired no))
Следующие три правила будут проверять правильно ли снаряжен пистолет.
(defrule check
(object (name [PPK]) (safety on) (magazine out)
?T<- (range-test (check no))
=>
(send [PPK] clear)
(modify ?T (check yes)
)
Правило check заключается в том, что если пистолет стоит на предохранителе (safety on), обойма вынута (magazine out) и пистолет не был проверен, то нужно очистить патронник и проверить, нет ли в нем патрона. Обработчик сообщений clear для класса pistol будет выглядеть следующим образом:
(defmassage-handler pistol clear ()
(dynamic-put chamber 0)
(ppinstance)
)
В первой строке объявляется, что clear является обрабртчиком сообщения для класса pistol, причем этот обработчик не требует передачи аргументов. Оператор во второй строке «очищает» патронник. Присвоение выполняется независимо от того, какое текущее значение имеет слот chamber, - 0 или 1. Оператор в третьей строке требует, чтобы экземпляр распечатал информацию о текущем состоянии своих слотов.
В следующих двух правилах обрабатываются ситуации, когда пистолет снаряжен неправильно, - не установлен на предохранитель или в него вставлена обойма. Правило correct1 устанавливает пистолет на предохранитель, а правило correct2 извлекает из него обойму.
(defrule correct1
(object (name [PPK]) (safety off) )
(range-test (check no))
=>
(send [PPK] safety on)
)
(defrule correct2
(object (name [PPK]) (safety on) (magazine in))
(range-test (check no))
=>
(send [PPK] drop)
)
Как при разработке предыдущего правила, нам понадобятся обработчики сообщений safety и drop.
(defmessage-handler pistol safety (?on-off)
(dynamic-put safety ?on-off)
(if (eq ?on-off on)
then (dynamic-put hammer down)
)
)
Обработчик сообщения safety принимает единственный аргумент, который может иметь только два символических значения on или off. В противном случае нам пришлось бы разработать два обработчика: один для сообщения safety-on, а другой – для сообщения safety-off. Учтите, что в некоторых моделях, например в Walther PPK, при установке пистолета на предохранитель патронник очищается автоматически.
Обработчик сообщения drop просто извлекает обойму из пистолета.
(defmessage-handler pistol drop ()
(dynamic-put magazine out)
)
Теперь, когда обеспечено правильное исходное снаряжение пистолета, можно приступить к стрельбе. Следующее правило обеспечивает вставку обоймы в пистолет перед стрельбой:
(defrule mag-in
(object (name [PPK]) (safety on ) (magazine out))
(range-test (fired no) (check yes))
=>
(send [PPK] seat)
)
Обработчик сообщения seat выполняет действия, противоположные тем, которые выполняет обработчик drop.
(defmessage-handler pistol seat ()
(dynamic-put magazine in)
)
Можно было бы, конечно, включить в программу и следующее правило mag-in:
(defrule mag-in
?gun <- (object (name [PPK]) (safety on ) (magazine out)) (range-test (fired no) (check yes))
=>
(modify ?gun (magazine in)
)
но это противоречит одному из принципов объектно-ориентированного программирования, который гласит, что объект должен самостоятельно обрабатывать содержащиеся в нем данные. Следующее правило обеспечивает снаряжение обоймы патронами:
(defrule load
(object (name [PPK]) (magazine in) (chamber 0))
=>
(send [PPK] rack)
)
На примере обработчика сообщения rack вы можете убедиться в справедливости нашего замечания о том, что обработку данных внутри объекта нужно поручать методам этого объекта, а не включать прямо в правило.
(defmessage-handler pistol rack ()
(if (> (dynamic-get rounds) 0)
then (dynamic-put chamber 1)
(dynamic-put rounds (- (dynamic-get rounds) 1))
(dynamic-put slide forward)
else (dynamic-put chamber 0)
(dynamic-put slide back)
)
)
В этом обработчике обеспечивается досылка патрона в патронник в том случае, если в обойме имеются патроны. Следующее правило подготавливает пистолет к стрельбе, снимая его с предохранителя. Обратите внимание на то, что в нем повторно используется сообщение safety, но на этот раз с аргументом off.
(defrule ready
(object (name [PPK]) (chamber 1))
=>
(send [PPK] safety off)
)
Правило fire выполняет стрельбу.
(defrule fire
(object (name [PPK]) (safety off);
?T <- (range-test (fired no))
=>
(if (eq (send [PPK] fire) TRUE)
then (modify ?T (fired yes)))
)
Обратите внимание, что в данном правиле используется обработчик сообщения, которое возвращает значение. Анализируя его, можно выяснить, произведен ли выстрел, т.е. выполнена ли в действительности та операция, которая «закреплена» за этим сообщением. Если в патроннике был патрон и пистолет был снят с предохранителя, то обработчик сообщения вернет значение TRUE (после того, как выведет на экран BANG!). В противном случае он вернет FALSE (после того, как выведет на экран click).
(defmessage-handler pistol fire ()
(if (and
(eq (dynamic-get chamber) 1)
(eq (dynamic-get safety) off)
)
then (printout t crlf “BANG!” t crlf)
TRUE
else (printout t crlf “click” t crlf)
FALSE
)
)
Пусть вас не смущает, что в обработчике сообщения анализируется условие, которое уже было проанализировано правилом, отославшим сообщение (в данном случае речь идет об условии safety off). Дело в том, что одно и тоже сообщение может отсылаться разными правилами и нет никакой гарантии, что в каждом из них будет проверяться это условие.
После завершения стрельбы пистолет нужно вновь вернуть в положение «по-походному». Начинается это с того, что пистолет устанавливается на предохранитель, для чего используется ранее разработанный обработчик сообщения safety.
(defrule unready
(object (name [PPK]) (safety off))
(range-test (fired yes))
=>
(send [PPK] safety on)
)
Следующая операция – вынуть обойму. Обратите внимание, что в нем мы вновь обращаемся к обработчику сообщения drop.
(defrule drop
(object (name [PPK]) (safety on))
(range-test (fired yes))
=>
(send [PPK] drop)
)
Последнее правило выбрасывает патрон из патронника, вызывая обработчик сообщения clear.
(defrule unload
(object (name [PPK]) (safety on) (magazine out))
range-test (fired yes))
=>
(send [PPK] clear)
)
В этом приемре было продемонстрировано, как в рамках единой CLIPS программы “уживаются” правила и объекты. Правила управляют ходом вычислений, но некоторые операции объекты выполняют и самостоятельно, получив “указание” (сообщение) от правил. Объекты не являютя резидентами рабочей памяти, но члены левой части правил (условий) могут быть сопоставлены с содержимым их слотов. Состояние объектов может измениться и вследствие побочных эффектов активизации правил, но я считаю, что лучше предоставить объектам возможность самостоятельно выполнять манипуляции с хранящимися в них данными в ответ на поступающие от правил сообщения. Объекты не могут самостоятельно активизировать правила, но их обработчики сообщения могут “возвращать” определенную информацию о результатах, которая используется для управления логикой выполнения действий в правой части правил.
А.4. ЗАДАЧА “ПРАВДОЛЮБЦЫ И ЛЖЕЦЫ”
Для того, чтобы продемонстрировать вам возможности языка CLIPS, я выбрал головоломку, а не задачу из практики применения экспертных систем. В головоломке решается одна из задач, возникающих на острове, населенном обитателями двух категорий: одни всегда говорят правду (назовем их правдолюбцами), а другие всегда лгут ( их, естественно, назовем лжецами). Множество подобных головоломок вы можете встретить на страницах занимательной книги Раймонда Смуляна «What is the Name of this Book?». Ниже приведены разные задачи из этой серии.
Р1. Встречаются два человека, А и В , один из которых правдолюбец, а другой – лжец. А говорит: «Либо я лжец, либо В правдолюбец». Кто из этих двоих правдолюбец, а кто лжец?
![](https://s.studizba.com/z.php?f=/templates/si/i/noavatar.png&w=100&h=100&t=1"){kind=avatar}
