DRIV_1 (Драйвер виртуального диска)

Создание загрузочного файла

драйвера устройства

В листинге 1 представлен диалог с системой при создании драйвера "DRIVER". Этот файл ассемблируется и линкуется как обычная программа, после чего преобразуется в двоичный .SYS файл. Замечу, что отсутствие стека для драйвера является нормальным явлением, так как драйвер при работе использует собственный стек MS-DOS.

В примере, приведенном в листинге 6-4, создается также выходной .LST файл ассемблера и выходной .MAP файл редактора связей. Конечно же, .OBJ и .EXE файлы могут быть удалены после создания .SYS файла.

Листинг 1.

Процесс создания простого драйвера.

C> masm driver,driver,driver;

Microsoft Macro Assembler Version 4.00

Copyright Microsoft Corp 1981, 1983, 1984, 1985.

All rights reserved.

45976 Bytes symbol space free

0 Warning Errors

0 severe Errors

C> link driver,driver,driver;

Microsoft 8086 Object linker

Version 3.00 Copyright Microsoft Corp 1983, 1984, 1985

Warning: no stack segment

C> exe2bin driver driver.sys

Драйвер виртуального диска

В листинге 2 приведен пример драйвера RAM-диска - драйвера виртуального диска, размещаемого в ОЗУ. Несмотря на свою простоту, драйвер работоспособен и может быть использован на любой MS-DOS системе начиная с версии 2.0 и выше. Данный драйвер RAM-диска, использует 360 Kбайт системной памяти для эмуляции стандартного пятидюймового дисковода. Но при использовании этого драйвера, система ПК должна иметь по крайней мере 512 Kбайт памяти. Если имеется меньше памяти или нужно просто иметь виртуальный диск меньших размеров, то можно изменить принимаемые по умолчанию параметры, описаные в секции драйвера "Описание RAM-диска".

После того, как программа была обработана ассемблером и редактором связей, надо переименовать ее в RDISK.SYS. И добавить в файл CONFIG.SYS командную строку :

DEVICE=RDISK.SYS

При первой же перезагрузке драйвер будет установлен как драйвер следующего по порядку дисковода. Ничего более для установки драйвера RDISK не требуется.

Доступ к RAM-диску возможен с помощью любых функций MS-DOS или программ, за исключением команд DISKCOPY и DISKCOMP. Обе эти программы ожидают определенные типы дисков и не работают с RAM-дисками.

Листинг 2.

Исходный текст драйвера RAM-диска

PAGE 60,132

; *** RDISK.ASM : MS-DOS ДРАЙВЕР RAM-ДИСКА ***

;

; Этот файл содержит исходный текст простого MS-DOS драйвера RAM-диска

; эмулирующего 360K флоппи-диск.

;

; В этом примере демонстрируются основные принципы построения драйвера

; устройств, включая один из методов, который можно использовать для

; отладки драйверов. Для установки этого драйвера включите в файл

; CONFIG.SYS строку "DEVICE=RDISK.SYS"

;

; ======== ВСПОМОГАТЕЛЬНЫЕ ФАЙЛЫ ДЛЯ ДРАЙВЕРА =====

;

INCLUDE driver.inc ; Константы для MS-DOS драйвера

IFDEF DEBUG

INCLUDE biosio.inc ; Определения для отладки

ENDIF

;

; ============ КОНСТАНТЫ ========================

;

; Ограничения,накладываемые версией MS-DOS на максимальный код команды

;

CMD_PRE_30 EQU 00Ch ; до MS-DOS версии 3.00

CMD_PRE_32 EQU 00Fh ; до MS-DOS версии 3.20

CMD_32 EQU 018h ; начиная с версии 3.20

;

IFDEF DEBUG

CR EQU 0Ah ; используются в отладочных

LF EQU 0Dh ; сообщениях

ENDIF

;

PAGE

;

; ============ ШАБЛОНЫ СТРУКТУР ==============

;

request EQU es:[di] ; указатель на блок запроса

;

; Структура заголовка запроса

;

reqhdr STRUC

rlength db ? ; размер блока запроса

unit db ? ; номер устройства

command db ? ; код команды

status dw ? ; возвращаемый статус

db 8 DUP (?) ; зарезервировано

reghdr ENDS

;

; Структура блока запроса для команды INIT

;

inithdr STRUC

db (type reqhdr) DUP (?)

units db ? ; количество устройств

endadro dw ? ; смещение и сегмент

endadrs dw ? ; адреса завершения

bpbtabo dw ? ; смещение и сегмент

bpbtabs dw ? ; таблицы BPB

devnum db ? ; номер устройства

inithdr ENDS

;

; Структура блока запроса для команды MEDIA CHECK

;

mchkhdr STRUC

db (type reqhdr) DUP (?)

mbd db ? ; описатель носителя

chande dw ? ; статус замены

volume dd ? ; указатель на имя тома

mchkhdr ENDS

;

; Структура блока запроса для команды BUILD BPB

;

bpbhdr STRUC

db (type reqhdr) DUP (?)

db ? ; описатель носителя

dd ? ; указатель на FAT

bpbptro dw ? ; смещение BPB

bpbptrs dw ? ; сегмент BPB

bpbhdr ENDS

;

; Структура блока запроса для команд чтения/записи

;

iohdr STRUC

db (type reqhdr) DUP(?)

db ? ; описатель носителя

bufprt dd ? ; адрес буфера

count dw ? ; кол-во байт/секторов

start dw ? ; # начального сектора

nuvol dd ? ; адрес нов. имени тома

iohdr ENDS

;

; Структура блока параметров BIOS (BPB)

;

bpbstrc STRUC

bps dw ? ; количество байтов в секторе

spau db ? ; кол-во секторов в кластере

nrs dw ? ; кол-во зарезервир. секторов

nft db ? ; количество копий FAT

nde dw ? ; кол-во элементов директория

nls dw ? ; кол-во логических секторов

md db ? ; байт описателя носителя

nfs dw ? ; размер FAT в секторах

bpbstrc ENDS

;

PAGE

;

; ============= НАЧАЛО КОДА ДРАЙВЕРА ================

;

_TEXT SEGMENT BYTE PUBLIC 'CODE'

ASSUME CS:_TEXT, DS:_TEXT, ES:NOTHING

ORG 0

ORIGIN EQU $

;

; ============= ЗАГОЛОВОК ДРАЙВЕРА ==============

;

dw -1,-1 ; указатель на след. драйвер

dw AT_IOCTL OR AT_OCRM OR AT_NET

dw offset STRATEGRY ; смещение СТРАТЕГИЙ

dw offset ПРЕРЫВАНИЙ ; смещение ПРЕРЫВАНИЙ

db 1,'CDEVICE' ; кол-во устройств/имя

;

; ======= ТАБЛИЦА АДРЕСОВ ОБРАБОТЧИКОВ КОМАНД ======

;

JUMPTAB LABEL WORD

dw offset INIT ; 0 - инициализация

dw offset MEDIA_CHECK ; 1 - проверка носителя

dw offset BUILD_BPB ; 2 - построить BPB

dw offset IOCTL_INPUT ; 3 - IOCTL ввод

dw offset READ ; 4 - ввод из устр-ва

dw offset READ_NOWAIT ; 5 - неразруш. ввод

dw offset INPUT_STATUS ; 6 - ввод статуса

dw offset INPUT_FLUSH ; 7 - сбросить ввод

dw offset WRITE ; 8 - вывод на устр-во

dw offset WRITE_VERIFY ; 9 - вывод с проверкой

dw offset OUTPUT_STATUS ; A - вывод статуса

dw offset OUTPUT_FLUSH ; B - сбросить вывод

dw offset IOCTL_OUTPUT ; C - вывод IOCTL

dw offset DEVICE_OPEN ; D - открыть устр-во

dw offset DEVICE_CLOSE ; E - закрыть устр-во

dw offset REMOVABLE ; F - носитель сменный?

dw offset NO_COMMAND ; 10

dw offset NO_COMMAND ; 11

dw offset NO_COMMAND ; 12

dw offset GENERIC_IOCTL ; 13 - Generic IOCTL

dw offset NO_COMMAND ; 14

dw offset NO_COMMAND ; 15

dw offset NO_COMMAND ; 16

dw offset GET_LOGICAL ; 17 - получить/устано-

dw offset SET_LOGICAL ; 18 - вить лог.устр-во

;

; ============ ОБЛАСТЬ ДАННЫХ ДРАЙВЕРА ==============

;

reg_ptr dd ? ; адрес блока запроса

max_cmd db CMD_PRE_30 ; максимально допустимый код

; ; команды

save_ss dw ? ; значение SS на входе

save_sp dw ? ; значение SP на входе

;

PAGE

;

; ============ ПРОГРАММА СТРАТЕГИЙ =============

;

STRATEGY PROC FAR

mov cs:word ptr [reg_ptr],bx

mov cs:word ptr [reg_ptr+2],es

ret

strategy ENDP

;

; ============ ПРОГРАММА ПРЕРЫВАНИЙ ===============

;

INTERRUPT PROC FAR

push ax ; сохранить все рабочие

push cx ; регистры

push dx

push bx

push bp

push si

push di

push ds

push es

;

push cs ; определим локальный сегмент

pop ds ; данных

;

mov word ptr save_ss,ss ; сохраним входное

mov word ptr save_sp,sp ; значение SS и SP

;

mov bx,cs ; установим локальный

mov ax,offset local_stack - 2 ; стек

mov ss,bx

mov sp,ax

;

les di,[req_ptr] ; получить адрес блока

mov bl,request.command ; запроса и команду

;

; установим заранее код ошибки на случай если команда неверная

;

mov ax,(ST_ERROR OR UNKNOWN_COMMAND)

cmp bl,[max_cmd] ; команда поддерживается ?

ja exit ; нет - отвергаем ее

;

; Выдаем указанную команду на выполнение соответствующему обработчику.

; Каждый обработчик получает управление с CS и DS установленными на

; сегмент драйвера и ES:DI указывающем на блок запроса. Свой статус

; обработчики возвращают в регистре AX.

;

xor bh,bh ; BX - индекс в таблице

shl bx,1 ; команд

IFDEF DEBUG

call print_command ; выдаем имя обрабатываемой

ENDIF ; команды

call word ptr jumptab[bx] ; вызываем обработчик

;

; Перешлем статус из регистра AX в слово состояния блока запроса

;

exit: push cs ; установка локального

pop ds ; сегмента данных

;

les di,[req_ptr] ; получим адрес блока запроса

or ax,ST_DONE ; установим бит DONE

mov request.status,ax ; сохраним статус

;

mov ss,word ptr save_ss ; восстановим значение

mov sp,word ptr save_sp ; регистров SS:SP

;

pop es ; восстановим содержимое

pop ds ; регистров

pop di

pop si

pop bp

pop bx

pop dx

pop cx

pop ax

ret

interrupt ENDP

;

PAGE

;

; ============ ОБРАБОТЧИКИ КОМАНД ==============

;

NO_COMAND PROC NEAR ; неподдерживаемая команда

ret ; возврат с ошибкой

NO_COMMAND ENDP

;

MEDIA_CHECK PROC NEAR ; 1 - проверка носителя

mov request.change,NotChanged

xor ax,ax

ret

MEDIA_CHECK ENDP

;

BUILD_BPB PROC NEAR ; 2 - построить BPB

mov request.bpbptro,offset bpb

mov request.bpbptrs,cs

xor ax,ax

ret

BUILD_BPB ENDP

;

IOCTL_INPUT PROC NEAR ; 3 - ввод IOCTL

xor ax,ax

ret

IOCTL_INPUT ENDP

;

READ PROC NEAR ; 4 - ввод из устройства

call verify ; проверка и установка параметров

jc rd_err ; выход по ошибке

les di,request.bufptr ; считываем в буфер

rep movsw ; передача

xor ax,ax ; нет ошибок

rd_err:

ret

READ ENDP

;

READ_NOWAIT PROC NEAR ; 5 - неразрушающий ввод

xor ax,ax ; без ожидания

ret

READ_NOWAIT ENDP

;

INPUT_STATUS PROC NEAR ; 6 - ввод статуса

xor ax,ax

ret

INPUT_STATUS ENDP

;

INPUT_FLUSH PROC NEAR ; 7 - сбросить входную очередь

xor ax,ax

ret

INPUT_FLUSH ENDP

;

WRITE PROC NEAR ; 8 - вывод на устройство

call verify ; проверка и установка параметров

jc wr_err ; выход при ошибке

push ds ; сохраним сегмент "сектора"

lds si,request.bufptr ; записываем из буфера

pop es ; на диск

xor di,di ; с нулевым смещением

rep movsw ; передача

xor ax,ax ; нет ошибок

wr_err:

ret

WRITE ENDP

;

WRITE_VERIFY PROC NEAR ; 9 - вывод с проверкой

call write

ret

WRITE_VERIFY ENDP

;

OUTPUT_STATUS PROC NEAR ; A - вывод статуса

xor ax,ax

ret

OUTPUT_STATUS ENDP

;

OUTPUT_FLUSH PROC NEAR ; B - сбросить выходную очередь

xor ax,ax

ret

OUTPUT_FLUSH ENDP

;

IOCTL_OUTPUT PROC NEAR ; C - вывод IOCTL

xor ax,ax

ret

IOCTL_OUTPUT

;

DEVICE_OPEN PROC NEAR ; D - открыть устройство

xor ax,ax

ret

DEVICE_OPEN ENDP

;

DEVICE_CLOSE PROC NEAR ; E - закрыть устройство

xor ax,ax

ret

DEVICE_CLOSE ENDP

;

REMOVABLE PROC NEAR ; F - носитель сменный ?

mov ax,ST_BUSY ; нет !

ret

REMOVABLE ENDP

;

GENERIC_IOCTL PROC NEAR ; 13 - групповой IOCTL запрос

xor ax,ax

ret

GENERIC_IOCTL ENDP

;

GET_LOGICAL PROC NEAR ; 17 - получить имя логического

xor ax,ax ; диска

ret

GET_LOGICAL ENDP

;